Thread: .:Bedah Default Config RB750 dan RB750G:.

dhcp-client add default route

Originally Posted by flazh

dhcp-client add default route

jawaban udah bener cuma terlalu singkat, silahkan di jelaskan lagi fungsi dari rule itu apa...biar yg masih belum paham bisa mengerti...dapet pahala loh....hehehehhe

ato point2 yg lain...1 2 3 4??mungkin mau membedah???

terutama yg masih baru gabung neh....mana???hayo semangat2...

kalo ga salah karena mengikuti yang atasnya udah dikasih ip pool ditambah range buat ipnya jadi tinggal mengikuti aja kaka ether 2 sebagai master..

point 1,2 ngerti..point 3,4 engga kaka..

pemula menunggu penjelasan dari para senior semua ah

Iseng .... sapa tahu jadi bener ...

1. ether2 jadi master nya ether3, ether4, ether5 jadi semua nya dalam 1 range ip address 192.168.88.1/24

2. ether 1 sebagai gateway, akses di berikan untuk rang dhcp ip 192.168.88.10-192.168.88.254, ether2 sebagai dhcp server, range dhcp 192.168.88.0/24 dgn 192.168.88.1 (ether2) sebagai ip server

3. default setting dapat menerima icmp, establish conn dari ether 1 (makanya set standar kudu psg modem di ether1), dan di NAT di ether1 untuk koneksi

4. kalo gak salah mirip no1 cuma buat mesin MAC

mohon koreksi

ikut ah... itung2 belajar ....

Code:

/interface set ether1 name=ether1-gateway   
merobah nama interface ether1 menjadi ether1-gateway 

/interface set ether2 name=ether2-local-master
merobah nama interface ether2 menjadi ether2-local-master

/interface set ether3 name=ether3-local-slave
merobah nama interface ether3 menjadi ether3-local-slave

/interface set ether4 name=ether4-local-slave
merobah nama interface ether4 menjadi ether4-local-slave


/interface set ether5 name=ether5-local-slave
merobah nama interfaceether5 menjadi ether5-local-slave



/interface ethernet set ether3-local-slave master-port=ether2-local-master
/interface ethernet set ether4-local-slave master-port=ether2-local-master
/interface ethernet set ether5-local-slave master-port=ether2-local-master
melakukan bonding ether3-local-slave,ether4-local-slave,ether5-local-slave
ke ether2-local-master

/ip address add address=192.168.88.1/24 interface=ether2-local-master comment="default configuration"

merobah ip ether2-local-master menjadi 192.168.88.1/24

Code:

/ip dhcp-client add interface=ether1-gateway disabled=no comment="default configuration";
membuat ether1-gateway sebagai client dhcp dari  ether2-local-master(dhcp server)

/ip pool add name=default-dhcp ranges=192.168.88.10-192.168.88.254;
range dhcp ip antara 192.168.88.10-192.168.88.254

/ip dhcp-server add name=default address-pool=default-dhcp interface=ether2-local-master disabled=no;
ther2-local-master(dhcp server)

/ip dhcp-server network add address=192.168.88.0/24 gateway=192.168.88.1 dns-server=192.168.88.1 comment="default configuration";
network : 192.168.88.0
mask:24(255.255.255.0)
gateway 192.168.88.1 & DNS 192.168.88.1 ((ether2-local-master)

Code:

filter add chain=input action=accept protocol=icmp comment="default configuration"
filter add chain=input action=accept connection-state=established in-interface=ether1-gateway comment="default configuration"
filter add chain=input action=accept connection-state=related in-interface=ether1-gateway comment="default configuration"
filter add chain=input action=drop in-interface=ether1-gateway comment="default configuration"
nat add chain=srcnat out-interface=ether1-gateway action=masquerade comment="default configuration"


pada bagian ini jujur ngga nyambung :th_beaten:

Code:

/tool mac-server remove [find]
/tool mac-server add interface=ether2-local-master disabled=no
/tool mac-server add interface=ether3-local-slave disabled=no
/tool mac-server add interface=ether4-local-slave disabled=no
/tool mac-server add interface=ether5-local-slave disabled=no

ngabungin mac buat konax nya winbox tanpa ip .....kale yaaah ????

/tool mac-server mac-winbox disable [find]
/tool mac-server mac-winbox add interface=ether2-local-master disabled=no
/tool mac-server mac-winbox add interface=ether3-local-slave disabled=no
/tool mac-server mac-winbox add interface=ether4-local-slave disabled=no
/tool mac-server mac-winbox add interface=ether5-local-slave disabled=no
??? mungkin ini bener.... untuk remote winbox pada ether2,3,4,5

/ip neighbor discovery set [find name=ether1-gateway] discover=no

tidak bisa di cari..????? tetangga...???

Setelah melihat2 dan mencoba menjawab... kok lelet adul sih gw.



Yang siap menjadi guru private Mikrotik untuk wilayah Banjarmasin (kalsel). bisa PM saya !..!!.


Br.

amien

1. ganti nama ether
bonding ether 3,4,5 ke ether 2
2. dhcp client ether1 terhubung ke dhcpserver ether2
dhcpserver ether2 config
3.?????????? ngga nyambung --belum bisa--
4. koneksi winbox dengan mac(tanpa ip) bisa dari ether2,3,4,5
koneksi winbox dgn IP bisa dari ether2,3,4,5
gateway mode tersembunyi

---------------

yup betul....

mantap ne....aku baru mau beli RB750G...semoga ilmu2 dia atas dapat membantu saya dalam meng config mikrotik

wah makin keren ne om ubur+cumi jadi

Code:

# these commands are executed after installation or configuration reset
:if ($action = "apply") do={
    /interface set ether1 name=ether1-gateway
    /interface set ether2 name=ether2-local-master
    /interface set ether3 name=ether3-local-slave
    /interface set ether4 name=ether4-local-slave
    /interface set ether5 name=ether5-local-slave

Setting up nama2 interface

Code:

    /interface ethernet set ether3-local-slave master-port=ether2-local-master
    /interface ethernet set ether4-local-slave master-port=ether2-local-master
    /interface ethernet set ether5-local-slave master-port=ether2-local-master

Set-up ether2 sebagai master port mode switch, dengan menjadikan ether3, 4 dan 5 sebagai slave dari ether2, master-slave mode bukan bonding, mirip bridge tp maennya di layer hardware.

Code:

    /ip address add address=192.168.88.1/24 interface=ether2-local-master comment="default configuration"

memberikan IP address pada interface ether2.

Code:

    :if ([:len [/system package find name="dhcp" !disabled]] != 0) do={
        /ip dhcp-client add interface=ether1-gateway disabled=no comment="default configuration";
        /ip pool add name=default-dhcp ranges=192.168.88.10-192.168.88.254;
        /ip dhcp-server add name=default address-pool=default-dhcp interface=ether2-local-master disabled=no;
        /ip dhcp-server network add address=192.168.88.0/24 gateway=192.168.88.1 dns-server=192.168.88.1 comment="default configuration";
    }

Cek jika package DHCP tidak ter-disable, kemudian setup DHCP client pada ether1 (WAN port), set pool address dengan range IP yang akan dibagikan oleh DHCP server, set DHCP server untuk menggunakan pool address tersebut pada ether2 (private LAN), assign default gateway, dns-server yang akan digunakan client.

Code:

    /ip firewall {
    	filter add chain=input action=accept protocol=icmp comment="default configuration"
	filter add chain=input action=accept connection-state=established in-interface=ether1-gateway comment="default configuration"
	filter add chain=input action=accept connection-state=related in-interface=ether1-gateway comment="default configuration"
	filter add chain=input action=drop in-interface=ether1-gateway comment="default configuration"

Setup filter firewall default, menerima semua packet icmp, menerima semua koneksi yang sedang berjalan pada port WAN, mendrop semua paket lainnya yang masuk dari arah WAN.

Code:

        nat add chain=srcnat out-interface=ether1-gateway action=masquerade comment="default configuration"
    }

Masquerade semua koneksi yang masuk lewat ether1 (WAN), client hanya akan melihat koneksi datang dari satu IP WAN yang sama (masquerade).

Code:

    /ip dns {
    	set allow-remote-requests=yes
    	static add name=router address=192.168.88.1
    }

set-up DNS proxy, set router address sesuai IP router.

Code:

    /tool mac-server remove [find]
    /tool mac-server add interface=ether2-local-master disabled=no
    /tool mac-server add interface=ether3-local-slave disabled=no
    /tool mac-server add interface=ether4-local-slave disabled=no
    /tool mac-server add interface=ether5-local-slave disabled=no

enablekan untuk mac-telnet hanya pada interface ether2 hingga 5,

Code:

    /tool mac-server mac-winbox disable [find]
    /tool mac-server mac-winbox add interface=ether2-local-master disabled=no
    /tool mac-server mac-winbox add interface=ether3-local-slave disabled=no
    /tool mac-server mac-winbox add interface=ether4-local-slave disabled=no
    /tool mac-server mac-winbox add interface=ether5-local-slave disabled=no

enablekan akses winbox hanya dari ether2 hingga 5.

Code:

    /ip neighbor discovery set [find name=ether1-gateway] discover=no
}

matikan discovery untuk neighbourhood dari port ether1 (WAN port), discovery dari winbox hanya terlihat dari ether2-5.

Code:

# these commands are executed if user requests to remove default configuration
:if ($action = "revert") do={
    /ip firewall {
        :local o [nat find comment="default configuration"]
        :if ([:len $o] != 0) do={ nat remove $o }

        :local o [filter find comment="default configuration"]
        :if ([:len $o] != 0) do={ filter remove $o }
    }

    :if ([:len [/system package find name="dhcp" !disabled]] != 0) do={
        :local o [/ip dhcp-server network find comment="default configuration"]
        :if ([:len $o] != 0) do={ /ip dhcp-server network remove $o }

        :local o [/ip dhcp-server find name="default" address-pool="default-dhcp" interface=ether2-local-master !disabled]
        :if ([:len $o] != 0) do={ /ip dhcp-server remove $o }

        /ip pool {
            :local o [find name=default-dhcp ranges=192.168.88.10-192.168.88.254]
            :if ([:len $o] != 0) do={ remove $o }
        }

        :local o [/ip dhcp-client find comment="default configuration"]
        :if ([:len $o] != 0) do={ /ip dhcp-client remove $o }
    }

    /ip dns {
    	set allow-remote-requests=no
        :local o [static find name=router address=192.168.88.1]
        :if ([:len $o] != 0) do={ static remove $o }
    }

    /ip address {
        :local o [find comment="default configuration"]
        :if ([:len $o] != 0) do={ remove $o }
    }

    /tool mac-server remove [find]
    /tool mac-server add interface=all disabled=no

    /tool mac-server mac-winbox remove [find interface!=all]
    /tool mac-server mac-winbox set [find] disabled=no 

    /ip neighbor discovery set [find name=ether1-gateway] discover=yes

    /interface ethernet set ether3-local-slave master-port=none
    /interface ethernet set ether4-local-slave master-port=none
    /interface ethernet set ether5-local-slave master-port=none

    /interface set ether1-gateway name=ether1
    /interface set ether2-local-master name=ether2
    /interface set ether3-local-slave name=ether3
    /interface set ether4-local-slave name=ether4
    /interface set ether5-local-slave name=ether5
}

Mengembalikan "default-configuration" menjadi bener2 default empty configuration.

Semoga berguna,

apakah mungkin.... ternyata master-port dan slave-port ini jika diimplementasikan dengan VLAN kita bisa mengisolir client yang terhubung kesetiap port-slave sehingga data dari setiap slave-port hanya bisa terhubung ke master-port tapi tidak bisa antar sesama slave-port?

blm sempat nyoba sih, abis kekurangan perangkat dah pada disetorin ke client karena mereka dah siap untuk instalasi perangkat